吾爱专用挂机[第二弹] (基于 VBS POST 0% CPU占用率)

乱码

本篇是继《吾爱论坛专用挂机脚本 [基于 VBS POST] [0% CPU占用率]》
后第二篇VBS版的吾爱专用挂机脚本。
修复后的脚本集成了 登陆，签到，挂机，掉线重连等功能于一身的强力脚本，
当然，依然是0% CPU占用率 0%网络占用 100%后台挂机，(纯天然，无毒无害..)
不影响正常的吾爱登录退出，始终后台挂机。

由于 meselson 朋友向我反馈说

脚本使用中发现一个问题，当网络环境不好时，脚本执行会超时退出，也许脚本中加入容错代码会更好一些。

我很开心，因为自己的劳动成果得到了部分人的认可，
所以我特地为此修复了脚本，还测试了一天，结果出奇的好。
下看看我在 2012-05-14 08:30 和 2012-05-15 09:11 截的图，绝对没有PS。

2012-05-14

      

2012-05-15

一天挂了多少小时，自己计算吧， 1535-1464=? 我算数不好...
不知道是我电脑问题，还是我不小心手抽筋点了两下导致双开了。。
反正就是这个结果，不知道吾爱的管会不会封我号。
我真的是无辜的。。

看代码，这是个VBS的类，复杂的都被写到类里了，只要调用一个 [挂机] 方法就OK了。

[帐号] = "帐号"         '用户名支持中文
[密码] = "密码"         '密码
[问题] = "编号"         '安全提问编号，下面是安全问题对应编号
[答案] = "答案"         '安全提问答案
'0.无安全提问(选此项请将答案设为空)
'1.母亲的名字
'2.爷爷的名字
'3.父亲出生的城市
'4.你其中一位老师的名字
'5.你个人计算机的型号
'6.你最喜欢的餐馆名称
'7.驾驶执照最后四位数字

Set [吾爱] = New [吾爱破解挂机类]
[吾爱].[挂机] [帐号], [密码], [问题], [答案]

Class [吾爱破解挂机类] '吾爱破解挂机类 v1.0
    '****************************************************
    '乱码领域 吾爱破解挂机类
    '****************************************************
    'v1.0 集成登陆，签到，挂机，掉线重连功能
    '****************************************************
    'Version:  1.0
    'Date   :  2012-05-13
    'Author :  乱码
    '源码献上,欢迎翻版。
    '****************************************************
    Private http, user, pwd, qst, ans
   
    Sub Class_Initialize  '类初始化事件
        Set http = CreateObject("Msxml2.ServerXMLHTTP")
    End Sub
   
    Public Function [挂机](u, p, q, a) '挂机初始化函数
        user = u
        pwd = p
        qst = q
        ans = a
        If login Then
            MsgBox "登录成功，即将开始挂机", 64+4096, "开始挂机"
            refresh 10 '10分钟刷新一次(设置为30分钟以内就好。)
        Else
            MsgBox "登录失败。。。", 48+4096, "登录失败"
        End If
    End Function
   
    Private Function refresh(minutes) '刷新页面函数(保持在线)
        Do
            If Not isOnLine Then
                CreateObject("Scripting.FileSystemObject").OpenTextFile("52pojielog.txt",8,1).WriteLine "脚本掉线 - " & Now
                '生成日志，记录掉线时间。'如果不需要就删除这句。
                login
            End If
            WScript.Sleep minutes * 60000
        Loop
    End Function
   
    Private Function isOnLine() '检查是否在线函数(集成签到功能)
        html = HttpGet("http://www.52pojie.cn/home.php?mod=task&do=apply&id=2")
        If html="" Or InStr(html,"您需要先登录才能继续本操作") Then
            isOnLine=False
        Else
            isOnLine =True
        End If
    End Function
   
    Private Function login() '登录函数
        Set reg = New RegExp
        reg.IgnoreCase = True
        reg.Global = True
        reg.MultiLine = True
        html = httpGet("http://www.52pojie.cn/member.php?mod=logging&action=login&infloat=yes&frommessage&inajax=1")
        reg.Pattern = "loginhash=([^""&]+)"
        If reg.Test(html) Then
            loginhash = reg.Execute(html).Item(0).Submatches(0)
            reg.Pattern = "name=.?formhash.?\s+value=['""]?([^""]+)"
            formhash = reg.Execute(html).Item(0).Submatches(0)
            postUrl  = "http://www.52pojie.cn/member.php?mod=logging&action=login&loginsubmit=yes&frommessage&inajax=1&loginhash=" & loginhash
            postData = "formhash=" & formhash & "&referer=http%3A%2F%2Fwww.52pojie.cn%2Fhome.php%3Fmod%3Dtask%26do%3Dview%26id%3D2&username=" & URLEncode(user) & "&password=" & URLEncode(pwd) & "&questionid=" & qst & "&answer=" & URLEncode(ans) & "&cookietime=2592000&loginsubmit=%3CSTRONG%3E%B5%C7%C2%BC%3C%2FSTRONG%3E"
            html = httpPost(postUrl,postData)
            login = InStr(html,"欢迎您回来")
        Else
            login = False
        End If
    End Function
   
    Private Function httpGet(url) 'get函数
        On Error Resume Next
        http.open "GET", url, False
        http.send
        httpGet = http.responseText
    End Function
   
    Private Function httpPost(url,data) 'post函数
        On Error Resume Next
        http.open "POST", url, False
        http.setRequestHeader "Content-Type", "application/x-www-form-urlencoded"
        http.send data
        httpPost = http.responseText
    End Function
   
    Private Function URLEncode(strURL) 'url编码函数 (如果需要UTF-8编码请找我)
        For I = 1 To Len(strURL)
            If Asc(Mid(strURL, I, 1)) < 0 Then
                tempStr = "%" & Right(CStr(Hex(Asc(Mid(strURL, I, 1)))), 2)
                tempStr = "%" & Left(CStr(Hex(Asc(Mid(strURL, I, 1)))), Len(CStr(Hex(Asc(Mid(strURL, I, 1))))) - 2) & tempStr
                URLEncode = URLEncode & tempStr
            ElseIf (Asc(Mid(strURL, I, 1)) >= 65 And Asc(Mid(strURL, I, 1)) <= 90) Or (Asc(Mid(strURL, I, 1)) >= 97 And Asc(Mid(strURL, I, 1)) <= 122) Or (Asc(Mid(strURL, I, 1)) >= 48 And Asc(Mid(strURL, I, 1)) <= 57) Then
                URLEncode = URLEncode & Mid(strURL, I, 1)
            Else
                URLEncode = URLEncode & "%" & Hex(Asc(Mid(strURL, I, 1)))
            End If
        Next
    End Function
End Class


亲们，下面的 相关帖子 里除了《吾爱论坛挂机工具》非本人作品外，
其余的都是我辛辛苦苦写出来的，没有抄袭，没有借鉴。
虽然有些可能有人发过了，但是我的绝对和他们不同。
希望大家帮忙顶一下，不然都沉的不见天日了。

忧郁小男生

谢谢分享啊  ，我的时间一直都上不去，郁闷死了

taozhulian

闲着没事自己一直看52呢 用不着 帮顶下

poboke

http://www.52pojie.cn/home.php?mod=task&do=apply&id=2
只是申请任务，还需要再打开一个完成任务的链接do=draw

小小沫涵

很不错 。谢谢~

乱码

poboke 发表于 2012-5-15 12:02
http://www.52pojie.cn/home.php?mod=task&do=apply&id=2
只是申请任务，还需要再打开一个完成任务的链接d ...

虽然不知道 do=draw 也可以完成任务，但是 这个已经有自动签到功能了，不信可以挂着试试啊。。

poboke

乱码 发表于 2012-5-15 12:21
虽然不知道 do=draw 也可以完成任务，但是 这个已经有自动签到功能了，不信可以挂着试试啊。。

我几天前就试过了

啤啤

这个已经挂了很久了 不错

乱码

啤啤 发表于 2012-5-15 12:53
这个已经挂了很久了 不错

我想请你帮忙测试一下，
在早上8点的样子，先截图看看时间，然后运行三次，
到第二天8点的样子,再截图，再看看是不是24小时。
随便把图回复到我这里。

我这挂了一天，竟然有71小时，所以我相当怀疑多开是多倍经验。

6267477ak

晕，难得有坐这么前的时候，你发的东西不会用啊，是不是把代码复制好放进txt，然后改下后缀?