计算机的开机
本帖最后由 TES286 于 2024-3-10 01:07 编辑计算机的开机,说着简单,但也有很多细节问题,大多数人并不是很清楚
不过,大概顺序就是这样:
> BIOS程序运行 -> 查找启动区 -> 跳转到系统 -> ......
按顺序讲解, 只是简单说说
# 1. 加载BIOS
首先, 按下开机键之后, 电源进行初始化, 以确保硬件的供电可靠, 准备好后, 主板上的硬件电路会将一些存在于各硬件ROM里的程序加载到RAM, 然后给CPU发复位(reset)信号
CPU在接到复位信号后, 开始执行, 但RAM内什么都没有, 但硬件工程师们肯定知道这种情况, 所以CPU会直接加载BIOS程序, 通常就在0xFFFF0处, 但这个位置只有16字节的空间, 所以常常只有一个JMP指令
也就是
```asm
jmp far f000:e05b ; 跳转到0xfe05b执行
```
紧接着BIOS会执行开机自检, 以及一系列跟初始化有关的东西
# 2. 加载启动区
如果一切完成, BIOS将会扫描每个硬盘设备(其实每个储存设备都行,包括硬盘,U盘,软盘,光盘,或者类似的东西)中0盘0道1扇区的内容,如果这一扇区的最后两字节是0x55 0xaa,BIOS就会认为它是启动区,并复制到内存0x7c00位置
复制完之后, BIOS将直接跳转到0x7c00, 也就是BIOS的使命终结了
> 为什么非要是 0x7c00 呢？BIOS开发团队是这样定的，改了会不兼容。
# 3. 系统内核
经过之前的努力, 终于进入了内核, 不过如果你聪明, 肯定知道启动区里绝对是要跳转的, 因为现代OS肯定大于512字节, 然后就是OS的代码了
OS的操作这里不提, 大概就是 设置中断,GDT,开保护模式,分页,然后规划内存, 然后启动系统各个进程
这里附Linux0.11的启动区bootsert.s (给自己挪个位, 输出Loading system ..., 加载磁盘中剩下的代码)
```asm
;
; SYS_SIZE is the number of clicks (16 bytes) to be loaded.
; 0x3000 is 0x30000 bytes = 196kB, more than enough for current
; versions of linux
;
SYSSIZE = 0x3000
;
; bootsect.s (C) 1991 Linus Torvalds
;
; bootsect.s is loaded at 0x7c00 by the bios-startup routines, and moves
; iself out of the way to address 0x90000, and jumps there.
;
; It then loads 'setup' directly after itself (0x90200), and the system
; at 0x10000, using BIOS interrupts.
;
; NOTE; currently system is at most 8*65536 bytes long. This should be no
; problem, even in the future. I want to keep it simple. This 512 kB
; kernel size should be enough, especially as this doesn't contain the
; buffer cache as in minix
;
; The loader has been made as simple as possible, and continuos
; read errors will result in a unbreakable loop. Reboot by hand. It
; loads pretty fast by getting whole sectors at a time whenever possible.
.globl begtext, begdata, begbss, endtext, enddata, endbss
.text
begtext:
.data
begdata:
.bss
begbss:
.text
SETUPLEN = 4 ; nr of setup-sectors
BOOTSEG= 0x07c0 ; original address of boot-sector
INITSEG= 0x9000 ; we move boot here - out of the way
SETUPSEG = 0x9020 ; setup starts here
SYSSEG = 0x1000 ; system loaded at 0x10000 (65536).
ENDSEG = SYSSEG + SYSSIZE ; where to stop loading
; ROOT_DEV: 0x000 - same type of floppy as boot.
; 0x301 - first partition on first drive etc
ROOT_DEV = 0x306
entry start
start:
mov ax,#BOOTSEG
mov ds,ax
mov ax,#INITSEG
mov es,ax
mov cx,#256
sub si,si
sub di,di
rep
movw
jmpi go,INITSEG
go: mov ax,cs
mov ds,ax
mov es,ax
; put stack at 0x9ff00.
mov ss,ax
mov sp,#0xFF00 ; arbitrary value >>512
; load the setup-sectors directly after the bootblock.
; Note that 'es' is already set up.
load_setup:
mov dx,#0x0000 ; drive 0, head 0
mov cx,#0x0002 ; sector 2, track 0
mov bx,#0x0200 ; address = 512, in INITSEG
mov ax,#0x0200+SETUPLEN ; service 2, nr of sectors
int 0x13 ; read it ; BIOS留的中断, 读文件
jnc ok_load_setup ; ok - continue
mov dx,#0x0000
mov ax,#0x0000 ; reset the diskette
int 0x13
j load_setup
ok_load_setup:
; Get disk drive parameters, specifically nr of sectors/track
mov dl,#0x00
mov ax,#0x0800 ; AH=8 is get drive parameters
int 0x13
mov ch,#0x00
seg cs
mov sectors,cx
mov ax,#INITSEG
mov es,ax
; Print some inane message
mov ah,#0x03 ; read cursor pos
xor bh,bh
int 0x10
mov cx,#24
mov bx,#0x0007 ; page 0, attribute 7 (normal)
mov bp,#msg1
mov ax,#0x1301 ; write string, move cursor
int 0x10
; ok, we've written the message, now
; we want to load the system (at 0x10000)
mov ax,#SYSSEG
mov es,ax ; segment of 0x010000
call read_it
call kill_motor
; After that we check which root-device to use. If the device is
; defined (!= 0), nothing is done and the given device is used.
; Otherwise, either /dev/PS0 (2,28) or /dev/at0 (2,8), depending
; on the number of sectors that the BIOS reports currently.
seg cs
mov ax,root_dev
cmp ax,#0
jne root_defined
seg cs
mov bx,sectors
mov ax,#0x0208 ; /dev/ps0 - 1.2Mb
cmp bx,#15
je root_defined
mov ax,#0x021c ; /dev/PS0 - 1.44Mb
cmp bx,#18
je root_defined
undef_root:
jmp undef_root
root_defined:
seg cs
mov root_dev,ax
; after that (everyting loaded), we jump to
; the setup-routine loaded directly after
; the bootblock:
jmpi 0,SETUPSEG
; This routine loads the system at address 0x10000, making sure
; no 64kB boundaries are crossed. We try to load it as fast as
; possible, loading whole tracks whenever we can.
;
; in: es - starting address segment (normally 0x1000)
;
sread: .word 1+SETUPLEN ; sectors read of current track
head: .word 0 ; current head
track: .word 0 ; current track
read_it:
mov ax,es
test ax,#0x0fff
die: jne die ; es must be at 64kB boundary
xor bx,bx ; bx is starting address within segment
rp_read:
mov ax,es
cmp ax,#ENDSEG ; have we loaded all yet?
jb ok1_read
ret
ok1_read:
seg cs
mov ax,sectors
sub ax,sread
mov cx,ax
shl cx,#9
add cx,bx
jnc ok2_read
je ok2_read
xor ax,ax
sub ax,bx
shr ax,#9
ok2_read:
call read_track
mov cx,ax
add ax,sread
seg cs
cmp ax,sectors
jne ok3_read
mov ax,#1
sub ax,head
jne ok4_read
inc track
ok4_read:
mov head,ax
xor ax,ax
ok3_read:
mov sread,ax
shl cx,#9
add bx,cx
jnc rp_read
mov ax,es
add ax,#0x1000
mov es,ax
xor bx,bx
jmp rp_read
read_track:
push ax
push bx
push cx
push dx
mov dx,track
mov cx,sread
inc cx
mov ch,dl
mov dx,head
mov dh,dl
mov dl,#0
and dx,#0x0100
mov ah,#2
int 0x13
jc bad_rt
pop dx
pop cx
pop bx
pop ax
ret
bad_rt: mov ax,#0
mov dx,#0
int 0x13
pop dx
pop cx
pop bx
pop ax
jmp read_track
/*
* This procedure turns off the floppy drive motor, so
* that we enter the kernel in a known state, and
* don't have to worry about it later.
*/
kill_motor:
push dx
mov dx,#0x3f2
mov al,#0
outb
pop dx
ret
sectors:
.word 0
msg1:
.byte 13,10
.ascii "Loading system ..."
.byte 13,10,13,10
.org 508
root_dev:
.word ROOT_DEV
boot_flag:
.word 0xAA55 ; 看看这里, 是不是以0xaa55结束?
.text
endtext:
.data
enddata:
.bss
endbss:
```
完 计算机的开机:
先把电源插上,然后按一下开机按钮,就行了! 高端的东西， 还要努力，这个还看不董！ 写的完全看不懂的样子， 收藏了有时间在看 很有意思，谢谢分享。 汇编指令学习周期多久啊 看似很简单的步骤，其实很复杂 楼主懂的好多好细致,我只知道55AA....