易语言Windows控制台程序怎么生成彩色文字
本帖最后由 20230713G001133 于 2024-1-15 21:15 编辑效果就像这样
color 参数
0 = 黑色 8 = 灰色
1 = 蓝色 9 = 淡蓝色
2 = 绿色 A = 淡绿色
3 = 浅绿色 B = 淡浅绿色
4 = 红色 C = 淡红色
5 = 紫色 D = 淡紫色
6 = 黄色 E = 淡黄色
7 = 白色 F = 亮白色 善用搜索引擎 一搜就有的 还要发帖
还有这种求助帖发悬赏区
.版本 2
.子程序 控制台_置标输出颜色, 逻辑型, 公开, 即设置 标准输出（1，内容）时的颜色
.参数 颜色, 整数型, , 只能是：1蓝色 2绿色 4红色(3蓝绿 文本色可用）
.参数 是否为背景色, 逻辑型, 可空, 真：背景色 假：文本色 默认为假
.局部变量 变量1, 整数型
.局部变量 变量2, 整数型
变量1 ＝ GetStdHandle (-11)
.如果真 (变量1 ＝ 0)
返回 (假)
.如果真结束
.如果 (是否为背景色)
返回 (SetConsoleTextAttribute (变量1, 128 ＋ 多项选择 (颜色, 16, 32, 0, 64)))
.否则
返回 (SetConsoleTextAttribute (变量1, 8 ＋ 颜色))
.如果结束
返回 (假)
.版本 2
.程序集 控制台类, , 公开
.程序集变量 标准输入, 整数型
.程序集变量 标准输出, 整数型
.程序集变量 标准错误, 整数型
.子程序 _初始化, , , 当基于本类的对象被创建后，此方法会被自动调用
.子程序 _销毁, , , 当基于本类的对象被销毁前，此方法会被自动调用
.子程序 创建, 整数型, 公开
.局部变量 a, 整数型
a ＝ AllocConsole ()
标准输入 ＝ GetStdHandle (-10)
标准输出 ＝ GetStdHandle (-11)
标准错误 ＝ GetStdHandle (-12)
返回 (a)
.子程序 标准输出, 逻辑型, 公开, 本参数提供内容所输出到的设备，可以为以下常量值之一： 1、#标准输出设备； 2、#标准错误设备。如果省略本参数，默认为“#标准输出设备”。成功返回真，失败返回假。
.参数 输出方向, 整数型, 可空, 本参数提供内容所输出到的设备，可以为以下常量值之一： 1、#标准输出设备； 2、#标准错误设备。如果省略本参数，默认为“#标准输出设备”。
.参数 欲输出文本, 文本型, , 欲输内容
.参数 欲输出颜色, 整数型, 可空, 一共有16种文字颜色，16种背景颜色，组合有256种。传入的值应当小于256；文字颜色：0=黑、1=蓝、2=绿、3=浅绿、4=红、5=紫、6=黄、7=白、8=灰、9=淡蓝、10=淡绿、11=淡浅绿、12=淡红、13=淡紫、14=淡黄、15=亮白；背景颜色：64=红、16=绿、32=蓝、128=INTENSITY以及它们的组合
.局部变量 nStdHandle, 整数型, , , 输出设备
.局部变量 color, 整数型, , , 颜色
.如果真 (是否为空 (输出方向) 或 输出方向 ＝ 1)
nStdHandle ＝ 标准输出
.如果真结束
.如果真 (输出方向 ＝ 2)
nStdHandle ＝ 标准错误
.如果真结束
.判断开始 (是否为空 (欲输出颜色))
color ＝ 15
.默认
color ＝ 欲输出颜色
.判断结束
SetConsoleTextAttribute (nStdHandle, color)
返回 (WriteConsole (nStdHandle, 欲输出文本, 取文本长度 (欲输出文本), 0, 0))
.子程序 标准输入, 文本型, 公开, 在标准输入设备上请求输入最多包含2048个字符的一行文本，返回用户所输入的内容。
.参数 输入时颜色, 整数型, 可空, 同对象.标准输出参数三
.局部变量 color, 整数型
.局部变量 缓冲区, 文本型
.判断开始 (是否为空 (输入时颜色))
color ＝ 15
.默认
color ＝ 输入时颜色
.判断结束
SetConsoleTextAttribute (标准输入, color)
缓冲区 ＝ 取空白文本 (2048)
ReadConsole (标准输入, 缓冲区, 取文本长度 (缓冲区), 0, 0)
缓冲区 ＝ 取文本左边 (缓冲区, 寻找文本 (缓冲区, #换行符, , 假) － 1)
返回 (缓冲区)
.子程序 置标题, 逻辑型, 公开, 设置或改写控制台窗口标题栏中的文字。成功返回真，失败返回假。
.参数 标题, 文本型
.如果真 (SetConsoleTitle (标题) ＝ 0)
返回 (假)
.如果真结束
返回 (真)
.子程序 换行, 逻辑型, 公开, 到下一行继续输入或输出。成功返回真，失败返回假。
返回 (标准输出 (, #换行符, ))
.子程序 销毁, 整数型, 公开
返回 (FreeConsole ())
jerryjian 发表于 2024-1-15 23:07
.版本 2
.程序集 控制台类, , 公开
提供一下那些dll命令 首席鉴淫师 发表于 2024-1-15 21:48
善用搜索引擎 一搜就有的 还要发帖
还有这种求助帖发悬赏区
大佬,你的字体好可爱, 能不能告知一下叫啥,十分感谢 20230713G001133 发表于 2024-1-16 06:30
提供一下那些dll命令
伸手党这么理直气壮的呢 20230713G001133 发表于 2024-1-16 06:30
提供一下那些dll命令
666666666666666666
页:
[1]