批处理 次数授权的代码模板及清除授权的血清代码
这里主要包含两部分，一部分是关于次数授权的批处理代码，主要功能是可以自动记录你是第几次运行这个批处理，达到设定次数后，在打开时就会提示授权失败什么的。。另一部分就是清除代码，主要是针对上面那个授权代码写得，主要功能就是清除打开次数记录的，相当于上面那把锁的钥匙
好了，这个我自己写的，也没有版权啥，随便用~
看代码，授权部分的
@echo off
setlocal
REM 定义注册表路径和值名称
set "REG_PATH=HKCU\Software\MyScripts\TrackOpenCount"
set "VALUE_NAME=OpenCount"
REM 检查注册表路径是否存在，如果不存在则创建它
reg query "%REG_PATH%" /ve 2>nul || (
echo 注册表路径不存在，正在创建...
reg add "%REG_PATH%" /f
set "count=0"
goto :incrementcount
)
REM 读取当前的计数（如果存在的话）
for /f "skip=2 tokens=3" %%i in ('reg query "%REG_PATH%" /v "%VALUE_NAME%" ') do (
set "count=%%i"
goto :incrementcount
)
REM 如果没有找到计数，则初始化为0（仅在路径存在但值不存在的情况下）
set "count=0"
:incrementcount
REM 增加计数
set /a "count+=1"
REM 将新的计数写入注册表中
reg add "%REG_PATH%" /v "%VALUE_NAME%" /d "%count%" /f
cls
REM 显示当前计数
echo 这是第 %count% 次打开这个批处理文件。
if %count% gtr 5 (
goto :HQ
) else (
goto :JX
)
:jx
rem 注意每个代码下的转跳标签，避免产生错误跳转
echo 这里填写5次以内（含5次）的代码
goto end
:hq
echo 这里填写打开次数超过5次以后的代码
goto end
:end
pause
下面这个是血清，也就是要是部分的代码：
@echo off
setlocal
REM 定义注册表路径和值名称
set "REG_PATH=HKCU\Software\MyScripts\TrackOpenCount"
set "VALUE_NAME=OpenCount"
REM 检查注册表路径是否存在
reg query "%REG_PATH%" /ve 2>nul || (
echo 注册表路径不存在，无需清除。
goto :end
)
REM 清除注册表路径及其下的所有键值
echo 正在清除注册表路径 %REG_PATH% 及其下的所有键值...
reg delete "%REG_PATH%" /f
:end
REM 脚本结束
echo 清除完成。
pause
额忘了效果图了，给你们上一张，是这个样子的大概
好了，分享完毕，喜欢的就留个言在走吧，要不然显得怪冷清的~ 虽然好像用不到。但感谢楼主创作并分享！ 试一试哈哈 52PJ070 发表于 2024-11-23 00:56
虽然好像用不到。但感谢楼主创作并分享！
还好，比如一些软件你需要推出试用版什么的，用这个方法就很好，，
页:
[1]