【极限小工具】微信免扫码切换用户bat-更新

limit7

功能介绍：
当我们有多个微信的时候，每次切换微信，都需要重新扫码，本脚本就是为了省去扫码这个步骤的。
如果微信使用了多开补丁，那么开多个微信也不需要每个都扫码了。
改了改了，不用那么麻烦了，现在脚本自动创建快捷方式
起因：本人有洁癖，不喜欢用第三方软件
开发语言/工具：bat、百度、VSCode
运行环境：WIN系统、安装了微信
特别说明：操作并不麻烦，一劳永逸，耐心设置一下即可。实际就是登录微信之前把配置文件从指定文件夹复制过来
配合微信多开补丁更好用，上个大佬的补丁链接

https://github.com/huiyadanli/RevokeMsgPatcher

使用说明：

• 把下面的代码复制到文本文档，并改名为wechatmore.bat
• 修改代码中WCPATH为自己电脑的微信配置目录，不知道的话登录微信后看 设置，文件管理。
• 修改代码中Program为微信程序目录，WeChat.exe目录
• 把脚本放到一个不容易删除的地方
• 双击运行脚本，会提示你输入当前配置文件对应的名称，输入完成之后，脚本会自动创建桌面快捷方式
• 需要创建其他快捷方式，请先登录其他微信，然后双击运行此脚本，输入名称即可。
  

运行截图：





代码如下：修改完另存为bat文件,可以根据需要自己修改内容

[PowerShell] 纯文本查看 复制代码

@echo off
cls
title 微信免扫码切换BAT - Coded by: [url=http://www.52pojie.cn]www.52pojie.cn[/url]--Limit7
::color 1F

Echo -------------------------------------------------------------
Echo         微信免扫码切换BAT    2021-05-10    Limit7
Echo -------------------------------------------------------------


SET WCPATH="C:\Users\%USERNAME%\Documents\WeChat~1\AllUse~1\config\"
:: WCPATH是config.data所在位置，请根据自己电脑情况修改
:: 路径最后的config后面有个\，一定要加上，不要忘了
SET Program="C:\Program Files (x86)\Tencent\WeChat\WeChat.exe"
:: Program是微信的安装路径

SET DATANAME="config.data"
SET PERSON=%1
if not exist %Program% (
        echo %Program%
        echo 未发现微信程序，请根据自己电脑情况修改
        pause
        exit
)
if not exist "%WCPATH%%DATANAME%" (
    echo 没有发现%DATANAME%配置文件
    echo 请检查%WCPATH%%DATANAME%路径是否正确
    echo 请检查是否登录过微信
        pause
        exit
)
if "%1"=="" (
        echo 正在启动微信
        start "" %Program%
        TIMEOUT /T 3 /NOBREAK
    call :BAK %0
    ) else (
    echo 正在登录微信【%PERSON%】...
    call :STARTLGOIN
    )
pause
exit

:STARTLGOIN
copy /y "%WCPATH%%PERSON%%DATANAME%" "%WCPATH%%DATANAME%"
start "" %Program%
echo 等待登陆，重新备份配置文件
TIMEOUT /T 12 /NOBREAK
copy /y "%WCPATH%%DATANAME%" "%WCPATH%%PERSON%%DATANAME%" 
echo 已重新备份
exit

:BAK
echo 提示：没有指定配置名称
echo 请输入当前登录配置名称：（例如：曹日天）
echo 将自动备份当前配置文件并创建快捷方式
SET /p NEW=
if /i "%NEW%"=="" (
    echo 需要指定当前配置文件的名称
    call :BAK %1
        exit
)else (
    copy /y "%WCPATH%%DATANAME%" "%WCPATH%%NEW%%DATANAME%" 
    echo 备份完成
        call :CREATEICO %1
        TIMEOUT /T 3 /NOBREAK
        pause
        exit
)
:CREATEICO
SET WorkDir=
SET Desc=%NEW%的微信
if not defined WorkDir call:GetWorkDir %1
(echo Set WshShell=CreateObject("WScript.Shell"^)
echo strDesKtop=WshShell.SPEcialFolders("DesKtop"^)
echo Set oShellLink=WshShell.CreateShortcut(strDesKtop^&"\%NEW%.lnk"^)
echo oShellLink.TargetPath=%1
echo oShellLink.Arguments="%NEW%"
echo oShellLink.WorkingDirectory="%WorkDir%"
echo oShellLink.IconLocation=%Program%
echo oShellLink.Windowstyle=1
echo oShellLink.Description="%Desc%"
echo oShellLink.Save)>makelnk.vbs
echo 正在创建桌面快捷方式
makelnk.vbs
del /f /q makelnk.vbs
goto :eof
:GetWorkDir
set WorkDir=%~dp1
set WorkDir=%WorkDir:~,-1%
goto :eof

叁块石头

limit7 发表于 2020-12-11 23:10
不难，就是找到微信配置文件夹，然后根据账号分别建立文件夹，把对应的配置文件放进你建的文件夹，再把ba ...

系统找不到指定的路径。
没有发现"config.data"配置文件
请检查"D:\weixin jilu\WeChat Files\All Users\config\""config.data"路径是否正确

老哥  大神  我改了下微信保存路径 为啥不行啊   这个路径没问题啊  提示的这是啥情况

limit7

七秒的记忆 发表于 2020-12-11 14:35
搞了半天没搞成

不难，就是找到微信配置文件夹，然后根据账号分别建立文件夹，把对应的配置文件放进你建的文件夹，再把bat里面的路径改一下，创建个快捷方式，改个名字就好。

数值

刚好我有二个微信，试试看能不能成功。

tangze88

看来不错的样子,下来试试

槿落沉眠

这个功能是实现微信免扫码(密码登陆？)，还是免扫码并自动读取密码登录微信？

sharokku4869

感谢楼主，我一直是用的修改版的微信，可以多开，回头试一下这个批处。

wdz2018

看着好麻烦，我还是扫个码得了

wanshiz

看介绍很方便的。试试看。谢谢了。

limit7

槿落沉眠 发表于 2020-12-11 11:46
这个功能是实现微信免扫码(密码登陆？)，还是免扫码并自动读取密码登录微信？

就是你有两个微信，用这个bat你可以提前设置好要登哪个微信，不用扫码切换了

limit7

小非凡 发表于 2020-12-11 12:04
免扫码切换登录？
是在有两个微信的时候？不用扫码，想等哪个就登哪个？

就是做多个快捷方式，打开微信的时候每个快捷方式读取你指定的配置文件，这样就不用换一个号扫一次码了