本帖最后由 limit7 于 2021-5-19 12:31 编辑
功能介绍：打开脚本，设置好当前微信配置文件的名称，脚本自动创建桌面快捷方式。真的很简单，不需要什么代码基础。而且特别干净，点开即用。
起因：本人有洁癖，不喜欢用第三方软件
开发语言/工具：bat、百度、VSCode
运行环境：WIN系统、安装了微信、需要知道怎么新建bat文件【可以百度】
特别说明：操作并不麻烦，一劳永逸，耐心设置一下即可。
配合微信多开补丁更好用，上个大佬的补丁链接
https://github.com/huiyadanli/RevokeMsgPatcher
使用说明：
0.看不懂的，不知道路径的，那就啥都不要改，直接复制新建个文本文档，复制代码到文本文档里，然后把【新建文本文档.txt】改成【wechatmore.bat】。放到一个不容易被删除的地方，双击运行就可以了。
- 把下面的代码复制到文本文档，并改名为wechatmore.bat
- 修改代码中WCPATH为自己电脑的微信配置目录，不知道的话，就默认不要修改
- 修改代码中Program为微信程序目录，WeChat.exe目录，不知道的话就不要修改，如果安装其他文件夹，就把代码里的【C:\Program Files (x86)\Tencent\WeChat\WeChat.exe】改成对应的文件夹。
- 把脚本放到一个不容易删除的地方
- 双击运行脚本，会提示你输入当前配置文件对应的名称，输入完成之后，脚本会自动创建桌面快捷方式。【杀毒会拦截，因为要创建快捷方式，请点信任。】
- 需要创建其他快捷方式，请先登录其他微信，然后双击运行此脚本，输入名称即可。
运行截图：
代码如下：
修改完另存为bat文件,可以根据需要自己修改内容
注意：WIN7用户请把 【C:\Users\%USERNAME%\Documents\WeChat~1\AllUse~1\config\】改成【C:\Users\%USERNAME%\Documents\WeChat Files\All Users\config\】
[PowerShell] 纯文本查看 复制代码 @echo off
cls
title 微信免扫码切换BAT - Coded by: [url=http://www.52pojie.cn]www.52pojie.cn[/url]--Limit7
::color 1F
Echo -------------------------------------------------------------
Echo 微信免扫码切换BAT 2021-05-10 Limit7
Echo -------------------------------------------------------------
:: WIN10这里路径不能有空格，需要用【WeChat~1\AllUse~1 】这种方式代替
:: SET WCPATH="C:\Users\%USERNAME%\Documents\WeChat~1\AllUse~1\config\"
SET WCPATH=C:\Users\%USERNAME%\Documents\WeChat~1\AllUse~1\config\
:: WCPATH是config.data所在位置，请根据自己电脑情况修改
:: 路径最后的config后面有个\，一定要加上，不要忘了
SET Program="C:\Program Files (x86)\Tencent\WeChat\WeChat.exe"
:: Program是微信的安装路径
SET DATANAME=config.data
:: SET DATANAME="config.data"
SET PERSON=%1
if not exist %Program% (
echo %Program%
echo 未发现微信程序，请根据自己电脑情况修改
pause
exit
)
if not exist "%WCPATH%%DATANAME%" (
echo 没有发现%DATANAME%配置文件
echo 请检查%WCPATH%%DATANAME%路径是否正确
echo 请检查是否登录过微信
pause
exit
)
if "%1"=="" (
echo 正在启动微信
start "" %Program%
TIMEOUT /T 3 /NOBREAK
call :BAK %0
) else (
echo 正在登录微信【%PERSON%】...
call :STARTLGOIN
)
pause
exit
:STARTLGOIN
copy /y "%WCPATH%%PERSON%%DATANAME%" "%WCPATH%%DATANAME%"
start "" %Program%
echo 等待登陆，重新备份配置文件
TIMEOUT /T 12 /NOBREAK
copy /y "%WCPATH%%DATANAME%" "%WCPATH%%PERSON%%DATANAME%"
echo 已重新备份
exit
:BAK
echo 提示：没有指定配置名称
echo 请输入当前登录配置名称：（例如：曹日天）
echo 将自动备份当前配置文件并创建快捷方式
SET /p NEW=
if /i "%NEW%"=="" (
echo 需要指定当前配置文件的名称
call :BAK %1
exit
)else (
copy /y "%WCPATH%%DATANAME%" "%WCPATH%%NEW%%DATANAME%"
echo 备份完成
call :CREATEICO %1
TIMEOUT /T 3 /NOBREAK
pause
exit
)
:CREATEICO
SET WorkDir=
SET Desc=%NEW%的微信
if not defined WorkDir call:GetWorkDir %1
(echo Set WshShell=CreateObject("WScript.Shell"^)
echo strDesKtop=WshShell.SPEcialFolders("DesKtop"^)
echo Set oShellLink=WshShell.CreateShortcut(strDesKtop^&"\%NEW%.lnk"^)
echo oShellLink.TargetPath=%1
echo oShellLink.Arguments="%NEW%"
echo oShellLink.WorkingDirectory="%WorkDir%"
echo oShellLink.IconLocation=%Program%
echo oShellLink.Windowstyle=1
echo oShellLink.Description="%Desc%"
echo oShellLink.Save)>makelnk.vbs
echo 正在创建桌面快捷方式
makelnk.vbs
del /f /q makelnk.vbs
goto :eof
:GetWorkDir
set WorkDir=%~dp1
set WorkDir=%WorkDir:~,-1%
goto :eof | 
[复制链接]
发表于 2021-5-19 10:31
