吾爱家园外交利器 v1.0 [VBS]

乱码

闲来无聊，写个小脚本玩玩。
本脚本的功能是访问说有当前在线用户的空间。
其他啥留言功能没敢往里写，不然就变成广告软件了。。

目的只是交流下编程技术，本脚本是POST技术的一个简单运用。
本次的VBS不要求在脚本上写帐号密码，但是必须用IE浏览器登录吾爱。
因为是基于IE浏览器的缓存和cookies，所以必须先登录吾爱，脚本才能正常运行。

验证效果如何，你可以等脚本运行完毕后，浏览器上退出吾爱，
然后去那些用户空间里看看有木有你的头像。
或者用其他浏览器，在没登录吾爱的状态下，去那些用户空间里看看有木有你的头像。

吾爱家园外交利器 v1.0

'Version:  1.0
'Date    :  2012-06-20
'Author :  乱码
'源码献上,欢迎翻版。

CmdMode "吾爱家园外交利器 v1.0  By.乱码","3f" '命令行模式运行

Set users = CreateObject("Scripting.Dictionary")
getUsers HttpGet("http://www.52pojie.cn/forum.php?showoldetails=yes")
names= users.Keys  '所有在线的用户名
urls = users.Items '所有在线的空间地址
WScript.Echo " 目前共:", users.Count, "人在线，开始外交活动..."
For i=0 To users.Count-1
    WScript.Echo vbCrLf, i+1, "正在访问【", names(i),"】的空间", vbCrLf, "空间地址是：", urls(i), vbCrLf
    HttpGet urls(i)'访问他的空间..
Next

WScript.Echo vbCrLf, "外交活动完毕！. . .", vbCrLf, vbCrLf, "请按任意键退出. . ."
WScript.StdIn.ReadLine

Function HttpGet(ByVal url)'读取网页
    With CreateObject("Msxml2.XMLHTTP")
        .open "GET", url, False
        .send
        HttpGet = .responseText
    End With
End Function

Function getUsers(strHtml)'读取在线用户
    Set re = New RegExp
    re.Global = True
    re.MultiLine = True
    re.Pattern = "<a href=""(http://www.52pojie.cn/space-uid-\d+.html)"">([^<]+)</a>"
    If re.Test(strHtml) Then
        For Each x In re.Execute(strHtml)
            If Not users.Exists(x.Submatches(1)) Then users.Add x.Submatches(1),x.Submatches(0)
        Next
    Else
        WScript.Echo vbCrLf, "无法读取在线用户，请先用IE浏览器登录吾爱！", vbCrLf, vbCrLf, "登录时，记得勾选上 ""自动登录"" 哦！", vbCrLf, vbCrLf, "请按任意键退出. . ."
        WScript.StdIn.ReadLine
        WScript.Quit
    End If
End Function

Function CmdMode(ByVal title,ByVal color)'命令行模式运行
    If LCase(Right(WScript.FullName,11)) = "wscript.exe" Then
        With CreateObject("Wscript.Shell")
            .Run "cmd /c title " & title & "&color " & color & "&Cscript //Nologo """ & WScript.ScriptFullName & """"
            .Run "taskkill /f /im cmd.exe",0
        End With
        WScript.Quit
    End If
End Function

PS:有的童鞋不会用VBS，这个我简单说明一下。
   把上面代码复制到记事本里，然后另存为"吾爱家园外交利器 v1.0.vbs"就好了。（如下图[以前的图片，懒得在截图了]）

阿杰

求楼主大大完善下之前的VBS 挂机软件啊  新增个数字ID登陆。

Sound

会VBS的都是大牛 小菜都看不懂代码

19nuclear91

支持大湿的作品 期待能稳定更新挂机工具

淡然出尘

膜拜VBS大牛、

不可一世

同求挂论坛在线时间工具。我以前的那些用在这个论坛明显悲剧了。一会就掉线。

gsl27

真牛啊，这代友好玩

OiO

我什么时候也能写这样的代码

凸~~凸

VBS的是大神啊  完全不会啊

Chief

大牛，此时此刻已经无法用言语表达我对你的敬佩，唯有以头像以表敬意。
你的记事本破解已经秒杀所有人，还有VBS玩的那么牛X。