[失效]115摇一摇脚本 v1.2 多帐号版 [VBS POST]

乱码

帖子已经更新
《115摇一摇脚本 v1.3 多帐号版 [VBS POST]》http://www.52pojie.cn/thread-161124-1-1.html


前几天我迷迷糊糊发现可以摇奖两次，今天特意测试了一下，确实可以摇奖两次、
早上摇一次，中午12点以后又可以摇一次。
大家都试试吧、我想应该不是我的帐号特别吧、、

后来有网友我在回复里说：

PS:刚才试了下，确实可以摇多次，看那个摇奖界面，似乎是增加了摇奖周期这个项目了，估计现在的周期是10多个小时，所以1天就可以要2次了。

我不了解115又在搞什么名堂，我都是脚本摇奖，所以也不知道现在什么情况、、
在网友的要求下，我更新了下脚本，改成多账户版的了，而且合适放开机启动项里
不过要先设置下 autoExit = 0 '自动退出开关

115摇一摇 v1.2(多帐号版)

这两个是同一天的、
目测应该是 00:00 - 12:00 一次，12:00 - 24:00 一次
大家都自己测试一下吧~~

好了，贴上简洁明了且不失霸气的代码吧、、

'Version: 1.2 (多帐号版)
'Date   : 2012-07-10
'Author : 乱码
'源码献上，欢迎翻版。

CmdMode "115摇一摇 v1.2(多帐号版) By.乱码","3f"

'用户名支持：邮箱、手机 和 数字帐号
user = Array( _
    "115帐号1" ,_
    "115帐号2" ,_
    "115帐号3" ,_
    "115帐号4" _
)
'密码要对应上面的用户名
pass = Array( _
    "115密码1" ,_
    "115密码2" ,_
    "115密码3" ,_
    "115密码4" _
)

autoExit = 0 '自动退出开关 [0不自动退出, 1自动退出]
'设置成1后摇奖完毕自动退出窗口、合适放开机启动项的朋友用。

For i=0 To UBound(user)
    Set http = CreateObject("Msxml2.ServerXMLHTTP")
    If login(user(i),pass(i)) Then
        code = getCode()
        If Len(code) Then
            Set o=getSpace(code)
            If o.state Then
                WScript.Echo user(i), "获得空间:", o.picked, ", 获得雨露:", o.Exp, ", 总空间:",  o.total_size
            Else
                WScript.Echo user(i), "摇奖失败 或者 已经摇过了"
            End If
        Else
            WScript.Echo user(i), "今天已经摇过了..."
        End If
    Else
        WScript.Echo user(i), "登录失败！..."
    End If
    Set http = Nothing
Next

If autoExit Then WScript.Quit
WScript.Echo vbCrLf, "按任意键退出..."
WScript.StdIn.ReadLine


Function HttpPost(ByVal url, ByVal data) 'POST函数
    With http
        .open "POST", url, False
        .setRequestHeader "Content-Type", "application/x-www-form-urlencoded"
        .send data
        HttpPost = .responseText
    End With
End Function

Function HttpGet(ByVal url) 'GET函数
    With http
        .open "GET", url, False
        .send
        HttpGet = .responseText
    End With
End Function

Function login(user,password) '登录函数
    url="http://passport.115.com/?ac=login"
    data="back=http%3A%2F%2Fwww.115.com&goto=http%3A%2F%2F115.com&login%5Baccount%5D=" & user & "&login%5Bpasswd%5D=" & password
    login = Len(HttpPost(url,data))<99
End Function

Function getCode() '读取摇奖码
    Set reg = New RegExp
    reg.IgnoreCase = True
    reg.Global = True
    reg.MultiLine = True
    reg.Pattern = "Yao\('(.*)',\s*function"
    html = HttpGet("http://115.com/?ct=index&ac=home")
    If reg.Test(html) Then getCode=Trim(reg.Execute(html).Item(0).Submatches(0)) Else getCode=""
End Function

Function getSpace(code) '摇奖
    url="http://115.com/?ct=ajax_user&ac=pick_space&token=" & code & "&_=" & Rnd
    Set getSpace = ParseJson(HttpGet(url))
End Function

Function ParseJson(strJson) 'JSON数据解析
    Set htmlfile = CreateObject("htmlfile")
    Set owindow = htmlfile.parentWindow
    owindow.execScript "var json_obj = " & strJson, "JScript"
    Set ParseJson = owindow.json_obj
End Function

Function CmdMode(ByVal title,ByVal color) '命令行模式运行
    If LCase(Right(WScript.FullName,11)) = "wscript.exe" Then
        With CreateObject("Wscript.Shell")
            .Run "cmd /c title " & title & "&color " & color & "&Cscript //Nologo """ & WScript.ScriptFullName & """"
            .Run "taskkill /f /im cmd.exe",0
        End With
        WScript.Quit
    End If
End Function

其实我除了脚本，啥也不会，求各位大大笼罩~~

Chief

那么牛逼，
我最喜欢摇一摇了。

984754551

教主就是不一样。话说脚本对象都不会~.很厉害的说！！

LoongKing

尼玛，看不懂啊，一堆代码，哥要的是程序啊，魂淡！.......

龙啸双节棍

脚本好呀，软件和脚本各有各的优缺点，，

xuliang

又有新发现了啊，大家都受益了！

Harrison

只会脚本的大人。。。

zxqwe

膜拜乱码大牛。。顺便看看。。

alters

非常帅气 支持一个 不错

米兰1899

谢谢啦拿走