自动翻页器v1.0(20231129)+鼠标连点器V4.0【AutoIt3编译】

zhaopengdoctor

【20240613更新下载链接】

【自动翻页器1.0.exe下载链接】（有效期30天，如大家之后还有需要我再找别的云盘）
https://cowtransfer.com/s/a1d89c56044247
解压密码：52pojie

【本帖之前的内容】文首向尊敬的版主致意：
原贴：鼠标连点器V3.0(20230613更新)【AutoIt3编译】
https://www.52pojie.cn/thread-1782431-1-1.html
(出处: 吾爱破解论坛)
在编辑时出现“抱歉，管理员设置了本版块发表于 60 天以前的主题自动关闭，不再接受新回复”的提示，已不能再编辑，故开个新贴。

更新的缘由：有坛友私信我，说非常需要连点次数限制这个功能，故在原软件基础上增加了该项功能。
新版本4.0界面如下：

使用方法：
1.设置点击频率，默认为10次/10秒，即每秒1次。
2.默认热键为左键F9、右键F10、停止F11。
按F9或F10开启左键或右键连点，期间按F10键或F9键可切换为右键或左键连点，按F11键停止连点。
在按下热键启动和停止时，相应的标签背景显示为红色。
也可以通过下拉菜单切换热键，可供选择的有Esc和F1~F10键。
3.4.0版本新增功能：
在停止条件栏中输入想要限制点击的次数，按热键启动后即可按设置好的点击频率点击，并在次数框内显示剩余次数。
期间可按停止热键暂停，并可按左键或右键热键继续计数。
在次数减为0后，自动停止点击，次数框内自动恢复为初始设置的次数。

【鼠标连点器V4.0.exe下载链接】（2024-05-10更新）
https://cowtransfer.com/s/35356bfdc77a40

源码如下：

[Asm] 纯文本查看 复制代码

#region ;**** 参数创建于 ACNWrapper_GUI ****
#PRE_Icon=favicon.ico
#PRE_Outfile=鼠标连点器4.0.exe
#PRE_UseX64=n
#PRE_Res_requestedExecutionLevel=None
#PRE_Add_Constants=y
#PRE_Run_Tidy=y
#endregion ;**** 参数创建于 ACNWrapper_GUI ****
$g_szVersion = "鼠标连点器4.0-ZPSoft-52pojie.cn"
If WinExists($g_szVersion) Then Exit ; 此脚本已经运行了
AutoItWinSetTitle($g_szVersion)
#include <ButtonConstants.au3>
#include <ComboConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
Opt("GUIOnEventMode", 1)

#region ### START Koda GUI section ### Form=
$Form1 = GUICreate("鼠标连点器4.0-ZPSoft-52pojie.cn", 437, 123, 192, 124)
GUISetOnEvent($GUI_EVENT_CLOSE, "Form1Close")
$Group1 = GUICtrlCreateGroup("频率", 20, 8, 120, 50)
$Input1 = GUICtrlCreateInput("10", 28, 28, 48, 21)
GUICtrlSetOnEvent(-1, "Input1Change")
$Label1 = GUICtrlCreateLabel("次/10秒", 80, 32, 48, 18)
GUICtrlCreateGroup("", -99, -99, 1, 1)
$Group2 = GUICtrlCreateGroup("热键", 160, 8, 120, 100)
$Label2 = GUICtrlCreateLabel("左键", 169, 32, 24, 18)
$Label3 = GUICtrlCreateLabel("右键", 169, 56, 24, 18)
$Label4 = GUICtrlCreateLabel("停止", 169, 80, 26, 18)
$Combo1 = GUICtrlCreateCombo("F1", 208, 28, 57, 25, BitOR($CBS_DROPDOWN, $CBS_AUTOHSCROLL))
GUICtrlSetData(-1, "F2|F3|F4|F5|F6|F7|F8|F9|F10|F11|Esc", "F9")
GUICtrlSetOnEvent(-1, "Combo1Change")
$Combo2 = GUICtrlCreateCombo("F1", 208, 52, 57, 25, BitOR($CBS_DROPDOWN, $CBS_AUTOHSCROLL))
GUICtrlSetData(-1, "F2|F3|F4|F5|F6|F7|F8|F9|F10|F11|Esc", "F10")
GUICtrlSetOnEvent(-1, "Combo2Change")
$Combo3 = GUICtrlCreateCombo("F1", 208, 76, 57, 25, BitOR($CBS_DROPDOWN, $CBS_AUTOHSCROLL))
GUICtrlSetData(-1, "F2|F3|F4|F5|F6|F7|F8|F9|F10|F11|Esc", "F11")
GUICtrlSetOnEvent(-1, "Combo3Change")
GUICtrlCreateGroup("", -99, -99, 1, 1)
$Pic1 = GUICtrlCreatePic("D:\autoit3\au3\logo.jpg", 20, 64, 120, 40)
$Group3 = GUICtrlCreateGroup("停止条件", 300, 8, 120, 100)
$Label5 = GUICtrlCreateLabel("次数", 309, 32, 24, 18)
$Input2 = GUICtrlCreateInput("", 348, 28, 48, 21)
GUICtrlSetOnEvent(-1, "Input2Change")
$Label8 = GUICtrlCreateLabel("次", 402, 32, 12, 18)
;~ $Label6 = GUICtrlCreateLabel("时间", 309, 56, 24, 18)
;~ $Input3 = GUICtrlCreateInput("", 348, 56, 48, 21)
;~ $Label9 = GUICtrlCreateLabel("秒", 402, 56, 12, 18)
$Radio1 = GUICtrlCreateRadio("无（条件清零）", 309, 56, 108, 17)
GUICtrlSetState($Radio1, $GUI_CHECKED)
GUICtrlSetOnEvent(-1, "Radio1selected")
GUICtrlCreateGroup("", -99, -99, 1, 1)
GUISetState(@SW_SHOW)
WinSetOnTop($g_szVersion, "", 1)
#endregion ### END Koda GUI section ###
Dim $i, $LorR, $times, $second, $count
Dim $list[12] = ["F1", "F2", "F3", "F4", "F5", "F6", "F7", "F8", "F9", "F10", "F11", "Esc"]
Dim $condition = 0
Dim $rate = 10
Dim $hotleft = "F9"
Dim $hotright = "F10"
Dim $hotstop = "F11"
freshcombolist()
HotKeySet("{" & $hotleft & "}", "leftstart")
HotKeySet("{" & $hotright & "}", "rightstart")
HotKeySet("{" & $hotstop & "}", "clickstop")

While 1
        If $i = 1 Then
                Select
                        Case $condition = 0 ;当选择无时，直接点击
                                MouseClick($LorR)
                        Case $condition = 1 ;限定次数
                                If $times > $count Then
                                        MouseClick($LorR)
                                        $count = $count + 1
                                        GUICtrlSetData($Input2, $times - $count)
                                Else
                                        clickstop()
                                        GUICtrlSetData($Input2, $times)
                                        $count = 0
                                EndIf
                EndSelect
                Sleep(10000 / $rate)
        EndIf
WEnd
Func leftstart()
        $LorR = "left"
        GUICtrlSetBkColor($Label2, 0xFF0000)
        GUICtrlSetBkColor($Label3, $GUI_BKCOLOR_TRANSPARENT)
        GUICtrlSetBkColor($Label4, $GUI_BKCOLOR_TRANSPARENT)
        $i = 1
EndFunc   ;==>leftstart
Func rightstart()
        $LorR = "right"
        $i = 1
        GUICtrlSetBkColor($Label2, $GUI_BKCOLOR_TRANSPARENT)
        GUICtrlSetBkColor($Label3, 0xFF0000)
        GUICtrlSetBkColor($Label4, $GUI_BKCOLOR_TRANSPARENT)
EndFunc   ;==>rightstart
Func clickstop()
        $i = 0
        GUICtrlSetBkColor($Label2, $GUI_BKCOLOR_TRANSPARENT)
        GUICtrlSetBkColor($Label3, $GUI_BKCOLOR_TRANSPARENT)
        GUICtrlSetBkColor($Label4, 0xFF0000)
EndFunc   ;==>clickstop
Func Form1Close()
        Exit
EndFunc   ;==>Form1Close
Func Input1Change()
        $rate = GUICtrlRead($Input1)
EndFunc   ;==>Input1Change
Func Combo1Change()
;~ 取消原有的热键，并重新定义新的热键
        HotKeySet("{" & $hotleft & "}")
        $hotleft = GUICtrlRead($Combo1)
        HotKeySet("{" & $hotleft & "}", "leftstart")
        freshcombolist()
EndFunc   ;==>Combo1Change
Func Combo2Change()
        HotKeySet("{" & $hotright & "}")
        $hotright = GUICtrlRead($Combo2)
        HotKeySet("{" & $hotright & "}", "rightstart")
        freshcombolist()
EndFunc   ;==>Combo2Change
Func Combo3Change()
        HotKeySet("{" & $hotstop & "}")
        $hotstop = GUICtrlRead($Combo3)
        HotKeySet("{" & $hotstop & "}", "clickstop")
        freshcombolist()
EndFunc   ;==>Combo3Change
Func freshcombolist()
;~         设置列表框1、2、3里的内容，不能与正在使用的热键重复
        Dim $n, $combolist = "|"
        For $n In $list
                If $n <> $hotright And $n <> $hotstop Then
                        $combolist = $combolist & $n & "|"
                EndIf
        Next
        GUICtrlSetData($Combo1, $combolist, $hotleft)
        Dim $n, $combolist = "|"
        For $n In $list
                If $n <> $hotleft And $n <> $hotstop Then
                        $combolist = $combolist & $n & "|"
                EndIf
        Next
        GUICtrlSetData($Combo2, $combolist, $hotright)
        Dim $n, $combolist = "|"
        For $n In $list
                If $n <> $hotleft And $n <> $hotright Then
                        $combolist = $combolist & $n & "|"
                EndIf
        Next
        GUICtrlSetData($Combo3, $combolist, $hotstop)
EndFunc   ;==>freshcombolist
;~  4.0新增功能
;~  限定次数
Func Input2Change()
;~         当文本框内容不为空，则radio1未选
        If GUICtrlRead($Input2) <> "" Then ;判断是否为空
                $times = GUICtrlRead($Input2)
                $condition = 1
                GUICtrlSetState($Radio1, $GUI_UNCHECKED)
        EndIf
EndFunc   ;==>Input2Change
;~ 当radio1选择，则input2为空
Func Radio1selected()
        $condition = 0
        GUICtrlSetData($Input2, "")
EndFunc   ;==>Radio1selected

zhaopengdoctor

xingye688 发表于 2023-11-7 07:55
能做一个上滑的么，不被侦测

模拟手势上划是吧？有需求就可以考虑，我试试看能不能实现，敬请关注

zhaopengdoctor

cqwsntjz 发表于 2023-11-13 16:20
关注关注关注！（有模拟手势功能，直接就起飞了）

新出炉帖子：自动翻页器V1.0(20231127首发)【AutoIt3编译】
https://www.52pojie.cn/thread-1862446-1-1.html
(出处: 吾爱破解论坛)
快去看看是不是你想要的功能~~~

aidjgo

问题会不会被检测出来？

别闹

简单好用。功能单一

blacktulip

收藏备用。

aa361328

标记备用！！！！！！

yh141632

感谢大佬！！

ohos9527

谢谢分享

cade035

感谢分享！

niaiwowoaini

留起来以后用

szwangbin001

有没有后台啊

Johnny0524

惯例收藏