关于易语言的超文本浏览框

jhclb1986

超文本浏览框中 没有滚动条这个属性， 那怎么设置 能固定边框，不要出现滚动条，或者其他组件可以实现这个功能的？
比如进百度首页，我只想显示图中的部分 其他都不显示 而且也不能拉滚动条

wenaiji1

超文本浏览框本身就有滚动条
可能窗口太小
浏览框大
所以没显示出来

超文本浏览框1.宽度 ＝ _启动窗口.宽度
超文本浏览框1.高度 ＝ _启动窗口.高度
不知道对不对

jhclb1986

wenaiji1 发表于 2013-3-26 16:52
超文本浏览框本身就有滚动条
可能窗口太小
浏览框大

是啊 本来就有的 而且不能设置  我就是想浏览网站时 不要让他出现滚动条 应该怎么做？

wenaiji1

jhclb1986 发表于 2013-3-26 16:58
是啊 本来就有的 而且不能设置  我就是想浏览网站时 不要让他出现滚动条 应该怎么做？

遮盖法，用外形框或标签或画板做底，上面套一个浏览器，然后浏览器的大小要大于底部，这样超出的部分就被底盖住了 不知道行不  再不行我也不知道了

jhclb1986

wenaiji1 发表于 2013-3-26 17:03
遮盖法，用外形框或标签或画板做底，上面套一个浏览器，然后浏览器的大小要大于底部，这样超出的部分就被 ...

用遮盖法的话  鼠标滑轮或者键盘方向键按的话 还是会动的    可以设置禁止鼠标滑轮吗

pppploi8

屏蔽
.版本 2

.局部变量 document, 对象
.局部变量 window, 对象

document ＝ documentFromDOM (超文本浏览框1.取窗口句柄 ())
window ＝ document.读对象型属性 (“parentWindow”, )
window.通用方法 (“execScript”, “var jie = document.createStyleSheet();jie.addRule('html','overflow:hidden;');”)

自定义数据类型
.版本 2

.数据类型 UUID
    .成员 Data1, 整数型
    .成员 Data2, 短整数型
    .成员 Data3, 短整数型
    .成员 Data4, 字节型, , "8"

常量
.版本 2

.常量 WM_HTML_GETOBJECT, "“WM_HTML_GETOBJECT”"
.常量 SMTO_ABORTIFHUNG, "2"

子程序
.版本 2
.支持库 spec

.子程序 IsIEServerWindow, 逻辑型
.参数 hwnd, 整数型
.局部变量 lRes, 整数型
.局部变量 sClassName, 文本型

sClassName ＝ 取空白文本 (255)
lRes ＝ API_GetClassName (hwnd, sClassName, 255)
sClassName ＝ 取文本左边 (sClassName, lRes)
返回 (sClassName ＝ “Internet Explorer_Server”)


.子程序 EnumChildProc, 逻辑型
.参数 hwnd, 整数型
.参数 lParam, 整数型

.如果真 (IsIEServerWindow (hwnd))
    API_CopyMemory (lParam, 取变量数据地址 (hwnd), 4)
    返回 (假)
.如果真结束
返回 (真)

.子程序 documentFromDOM, 对象
.参数 hwnd, 整数型
.局部变量 IID_IHTMLDocument, UUID
.局部变量 lRes, 整数型
.局部变量 lMsg, 整数型
.局部变量 hr, 整数型
.局部变量 document, 对象
.局部变量 SHwnd, 整数型

.如果真 (hwnd ≠ 0)
    SHwnd ＝ hwnd
    .如果真 (取反 (IsIEServerWindow (SHwnd)))
        API_EnumChildWindows (SHwnd, 到整数 (&EnumChildProc), 取变量数据地址 (SHwnd))
    .如果真结束
    lMsg ＝ API_RegisterWindowMessage (#WM_HTML_GETOBJECT)
    API_SendMessageTimeout (SHwnd, lMsg, 0, 0, #SMTO_ABORTIFHUNG, 1000, lRes)
    ' IID_IHTMLDocument GUID:{626FC520-A41E-11CF-A731-00A0C9082637}
    IID_IHTMLDocument.Data1 ＝ 1651492128
    IID_IHTMLDocument.Data2 ＝ 42014
    IID_IHTMLDocument.Data3 ＝ 4559
    IID_IHTMLDocument.Data4 [1] ＝ 167
    IID_IHTMLDocument.Data4 [2] ＝ 49
    IID_IHTMLDocument.Data4 [3] ＝ 0
    IID_IHTMLDocument.Data4 [4] ＝ 160
    IID_IHTMLDocument.Data4 [5] ＝ 201
    IID_IHTMLDocument.Data4 [6] ＝ 8
    IID_IHTMLDocument.Data4 [7] ＝ 38
    IID_IHTMLDocument.Data4 [8] ＝ 55
    .如果真 (lRes ≠ 0)
        hr ＝ API_ObjectFromLresult (lRes, IID_IHTMLDocument, 0, document)
    .如果真结束
    API_ZeroMemory (IID_IHTMLDocument, API_LocalSize (IID_IHTMLDocument))
.如果真结束
返回 (document)

API命令
.版本 2

.DLL命令 API_ObjectFromLresult, 整数型, "OLEACC.DLL", "ObjectFromLresult", , 　
    .参数 lResult, 整数型
    .参数 riid, UUID, 传址
    .参数 wParam, 整数型
    .参数 ppvObject, 对象, 传址

.DLL命令 API_RegisterWindowMessage, 整数型, "user32", "RegisterWindowMessageA", , 获取分配给一个字串标识符的消息编号　&C000 到 &FFFF之间的一个消息编号。零意味着出错
    .参数 lpString, 文本型, , 注册消息的名字;  

.DLL命令 API_ZeroMemory, , "kernel32.dll", "RtlZeroMemory", , 将一块内存置零　
    .参数 Destination, UUID
    .参数 Length, 整数型

.DLL命令 API_SendMessageTimeout, 整数型, "user32", "SendMessageTimeoutA", , 向窗口发送一条消息。如窗口位于不同的线程中，则利用这个函数可以指定一个超时值，以便在另一个进程挂起的时候防止调用进程也永远挂起　成功时返回TRUE，失败时返回FALSE。会设置GetLastError
    .参数 hwnd, 整数型, , 要接收消息的一个窗口的句柄
    .参数 msg, 整数型
    .参数 wParam, 整数型, , 由消息决定
    .参数 lParam, 整数型, , 由消息决定
    .参数 fuFlags, 整数型, , 下述常数的一个或多个;SMTO_ABORTIFHUNG：如目标进程挂起，则函数立即返回;SMTO_BLOCK：除非函数返回，否则调用线程不能处理消息;SMTO_NORMAL：允许调用线程处理消息，同时保持函数继续执行
    .参数 uTimeout, 整数型, , 超时值，采用毫秒为单位
    .参数 lpdwResult, 整数型, 传址, 用于装载函数结果的一个变量;

.DLL命令 API_LocalSize, 整数型, "kernel32", "LocalSize", , 返回本地内存块大小　
    .参数 hMem, UUID

.DLL命令 API_EnumChildWindows, 整数型, "user32", "EnumChildWindows", , 为指定的父窗口枚举子窗口　非零表示成功，零表示失败
    .参数 父窗口句柄, 整数型, , 欲枚举子窗口的父窗口的句柄
    .参数 函数指针, 整数型, , 为每个子窗口调用的函数的指针。用AddressOf运算符获得函数在一个标准模块中的地址
    .参数 自定义值, 整数型, , 在枚举期间，传递给dwcbkd32.ocx定制控件之EnumWindows事件的值。这个值的含义是由程序员规定的。（原文：Value that is passed to the EnumWindows event of the dwcbkd32.ocx custom control during enumeration. The meaning of this value is defined by the programmer.）;  

.DLL命令 API_GetClassName, 整数型, "user32", "GetClassNameA", , 为指定的窗口取得类名　以字节数表示的类名长度；排除最后的空中止字符。零表示出错。会设置GetLastError
    .参数 窗口句柄, 整数型, , 欲获得类名的那个窗口的句柄
    .参数 缓冲区, 文本型, , 随同类名载入的缓冲区。预先至少必须分配nMaxCount+1个字符
    .参数 缓冲区长度, 整数型, , 由lpClassName提供的缓冲区长度;

.DLL命令 API_CopyMemory, , "kernel32", "RtlMoveMemory", , 　
    .参数 pDest, 整数型
    .参数 pSrc, 整数型
    .参数 ByteLen, 整数型









原帖地址：http://bbs.eyuyan.com/read.php?tid=231572

小明无敌

pppploi8 发表于 2013-3-26 19:45
屏蔽
.版本 2

documentFromDOM
俺不懂  

pppploi8

小明无敌 发表于 2013-3-26 19:48
documentFromDOM
俺不懂

最下面，原帖地址← ← 里面有源码下载

小明无敌

pppploi8 发表于 2013-3-26 19:50
最下面，原帖地址← ← 里面有源码下载

没用户怎么办