[已经失效]115摇一摇脚本 v1.5 多帐号版 [VBS POST]

乱码

明天更新，本次115更新了登录，采用加密登录。虽然写完了脚本，但是没多余帐号测试了，也找不到热心朋友测试、、
2013-04-22 20:48:32
---------------------------------------邪恶的分割线---------------------------------------
再次更新，本次115更新了摇奖地址，所以导致之前脚本失效。现在(2013-04-16 09:48:03) 已更新。
---------------------------------------邪恶的分割线---------------------------------------
昨天刚更新的，今天115就修改了数据，真是万恶的115。
现在(2013-04-10 09:21:04)已经更新。

连续两天，收到6位朋友私信，说115网盘脚本失效了。
那脚本我都忘了是什么时候写的了，虽说115那事已经过去很久，看样子还是有很多朋友留着当仓库的。
那么我也不能辜负大家的期望，今天中午抽空更新了下。
简单的分析了115，发现只是登录协议换了下，由原先的 https 改成了 http，其他都没有发生变化。


(4月16日 更新)

下面源码放出...

CmdMode "115摇一摇 v1.5(多帐号版) By.乱码","3f"

'用户名支持：邮箱、手机 和 数字帐号
user = Array( _
    "115帐号1" ,_
    "115帐号2" ,_
    "115帐号3" ,_
    "115帐号4" _
)
'密码要对应上面的用户名
pass = Array( _
    "115密码1" ,_
    "115密码2" ,_
    "115密码3" ,_
    "115密码4" _
)
autoExit = 0 '自动退出开关 [0不自动退出, 1自动退出]

For i=0 To UBound(user)
    Set http = CreateObject("Msxml2.ServerXMLHTTP")
    If login(user(i),pass(i)) Then '登录
        code = getCode() '获取摇奖码
        If Len(code) Then
            Set o=getSpace(code) '摇奖，返回json对象
            If o.state Then '判断摇奖状态
                '返回数据样例：{"state":true,"picked":"88MB","picked_num":88,"flag":false,"total_size":"71829MB","used_percent":"28%","exp":985}
                WScript.Echo vbCrLf, user(i), "本次摇奖信息：", vbCrLf, "获得空间:", o.picked, ", 获得雨露:", o.Exp, ", 总空间:",  o.total_size, ", 已经使用:",  o.used_percent
            Else
                WScript.Echo vbCrLf, user(i), "摇奖失败 或者 已经摇过了"
            End If
        Else
            WScript.Echo vbCrLf, user(i), "今天已经摇过了..."
        End If
    Else
        WScript.Echo vbCrLf, user(i), "登录失败！..."
    End If
    Set http = Nothing
Next

If autoExit Then WScript.Quit '是否自动退出
WScript.Echo vbCrLf, "按任意键退出..."
WScript.StdIn.ReadLine


Function HttpPost(url, data) 'POST函数
    With http
        .open "POST", url, False
        .setRequestHeader "Content-Type", "application/x-www-form-urlencoded"
        .send data
        HttpPost = .responseText
    End With
End Function

Function HttpGet(url) 'GET函数
    With http
        .open "GET", url, False
        .send
        HttpGet = .responseText
    End With
End Function

Function login(user, password) '登录函数
    url = "http://passport.115.com/?ac=login"
    data= "login%5Baccount%5D=" & user & "&login%5Bpasswd%5D=" & password
    login=Len(HttpPost(url,data))<999
End Function

Function getCode() '读取摇奖码
    Set reg = New RegExp
    reg.IgnoreCase = True
    reg.Global = True
    reg.MultiLine = True
    reg.Pattern = "take_token: '([^']+)',"
    html = HttpGet("http://115.com/")
    If reg.Test(html) Then getCode=Trim(reg.Execute(html).Item(0).Submatches(0)) Else getCode=""
End Function

Function getSpace(code) '摇奖
    url = "http://115.com/?ct=ajax_user&ac=pick_spaces&u=1&token=" & code & "&_=" & Rnd
    Set getSpace = ParseJson(HttpGet(url))
End Function

Function ParseJson(strJson) 'JSON数据解析
    Set htmlfile = CreateObject("htmlfile")
    Set owindow = htmlfile.parentWindow
    owindow.execScript "var json_obj = " & strJson, "JScript"
    Set ParseJson = owindow.json_obj
End Function

Function CmdMode(title, color) '命令行模式运行
    If LCase(Right(WScript.FullName,11)) = "wscript.exe" Then
        With CreateObject("Wscript.Shell")
            .Run "cmd /c title " & title & "&color " & color & "&Cscript //Nologo """ & WScript.ScriptFullName & """"
            .Run "taskkill /f /im cmd.exe",0
        End With
        WScript.Quit
    End If
End Function

附件下载:
115摇一摇 v1.5(多帐号版).rar (1.59 KB, 下载次数: 55)

2013-4-16 09:49 上传

点击文件名下载附件

taotao

学习一下，谢谢

1002217709

自从115禁止分享后我都懒得摇了

花葬

我都不去115了，直接百度

l363412580

学习了，谢谢LZ

娿丶怖娃娃

要那么多账号记不住阿！

jzwt716824

好东西 啊 学习了哦。。

woaililuovip

115太坑爹了。我去，都不想用它

matao5168

厉害，源码呢

小南瓜

谢谢楼主分享