[batch] 写了个自动切换内外网的脚本

hoochanlon

当前状况&优化：经常需要在同一台主机上进行内外网切换，处理生产域控需要进内网，平时浏览网页需要外网，已存在的内网与外网脚本，每次都要分别点一次不方便。

设计思路：判断是否为静态或自动获取，然后根据“自动获取”设置静态IP，如果是静态IP就设置自动获取，以达到自动识别与切换的目的。

源码及地址：

• https://github.com/hoochanlon/scripts/blob/main/d-bat-dc

  • 自动内外网识别与切换.bat

@echo off
cls

:: 定义接口名称
set interface="以太网"

:: 创建一个临时文件存储 netsh 输出
set temp_file=%temp%\dhcp_status_output.txt

:: 获取接口配置信息并保存到文件
netsh interface ip show config name=%interface% > "%temp_file%"

:: 初始化变量
set dhcp_status=

:: 逐行读取文件，查找 "DHCP 已启用"
for /f "tokens=2 delims=:" %%a in ('findstr /c:"DHCP 已启用" "%temp_file%"') do (
    set dhcp_status=%%a
)

:: 清理前导空格
for /f "tokens=* delims= " %%b in ("%dhcp_status%") do set dhcp_status=%%b

:: 显示结果，检查 DHCP 状态
echo 当前 DHCP 状态: "%dhcp_status%"

:: 判断当前模式并执行切换
if /i "%dhcp_status%"=="是" (
    echo 检测到当前为 DHCP 模式，正在切换到静态 IP...
    netsh interface ip set address name=%interface% source=static addr=172.16.1.55 mask=255.255.255.0 gateway=172.16.1.254 >nul 2>nul
    netsh interface ip set dnsservers %interface% static 172.16.1.6 validate=no >nul 2>nul
    echo 已切换到静态 IP 配置。
) else (
    echo 检测到当前为静态 IP 模式，正在切换到 DHCP...
    netsh interface ip set address name=%interface% source=dhcp >nul 2>nul
    @rem netsh interface ip set dnsservers %interface% dhcp >nul 2>nul
    netsh interface ip set dnsservers %interface% static 192.168.1.250 primary >nul 2>nul
    netsh interface ip add dnsservers %interface% 114.114.114.114 index=2 >nul 2>nul
    echo 已切换到 DHCP 配置。
)

:: 删除临时文件
del "%temp_file%"

@REM pause
:: 等待 3 秒后退出
@REM timeout /t 3 /nobreak >nul

代码效果:

静态设置成DHCP

DHCP设置成静态

goblack

思考！震惊。这玩意儿竟然值得用IDE编写。。。

这是单文件自动判断处理。相当于“自锁开关”，一键处理

我是写了多个文件，运行不同的脚本一键切换为DHCP或者不同网段，或者同时添加多个网段

如果切换很频繁的时候，也不是太容易判断当前网络位置，所以后来我还是写了个小软件，常驻图标显示当前网络是红、黄、绿区。。。避免在公网访问了内网资源导致内网DNS信息泄露这些问题。

goblack

sondycnc 发表于 2024-11-28 16:52
期待大佬作品

https://github.com/Icingworld/NetTool
https://github.com/nek0us/IPv4-Config-Switch

看了下网上类似的有。。。
不过我的不一样。目前的版本还是太LOW，比如网络都是写死的，IP都是改配置文件的。。。
如果公开分享，我来做的话，除了现有的图标，方案要可以自定义而不是固定3个方案，还有快捷键

baishibukele

这个功能实在太有用了

dxxiong

不错，有用，支持一下~

goblack

话说我还有个建议。。。。尾部pause之后不一定是结束。毕竟已经pause了没必要再往后面添加timeout。
可以直接goto 开头，反复一键切换

silent117

如果你忘了当前网络环境，不如按数字选择
在选择界面显示当前的网络环境，好做判断。

土鸡炖蘑菇

直接添加两个ip不就好了吗，省的切换了，不过外网dhcp的话 有可能会ip冲突罢了

hoochanlon

goblack 发表于 2024-11-28 15:37
思考！震惊。这玩意儿竟然值得用IDE编写。。。

这是单文件自动判断处理。相当于“自锁开关”，一键处理
...

常驻图标显示当前网络是红、黄、绿区，是在任务栏加小点图标吗？pause和timeout是做代码调试的时候用了，所以没删，单纯注释。网络位置，工位上有内外网线标识的。

goblack

hoochanlon 发表于 2024-11-28 16:15
常驻图标显示当前网络是红、黄、绿区，是在任务栏加小点图标吗？pause和timeout是做代码调试的时候用了， ...

对的。。。。随意用VB写了个小软件。。不到20KB。upx下就3KB.。。。。

不是怕插网线搞错，是经常切换，在用的时候搞错当前网络

guihai3

学习学习